prototype(GesagtGetan.Basic:Menu) < prototype(Neos.Neos:Menu) {
    @context {
        entryLevel = ${this.entryLevel}
        instanceFilter = ${this.instanceFilter}
        wrapAnchorWithSpan = ${this.wrapAnchorWithSpan}
        config = GesagtGetan.Basic:Config
    }

    templatePath = 'resource://GesagtGetan.Basic/Private/Fusion/Menu/Menu.html'
    sectionName = 'Menu'
    filter = 'Neos.Neos:Document,!GesagtGetan.Basic:NotInMenu'
    instanceFilter = ${String.replace('[instanceof ' + Array.join(String.split(this.filter, ','), '][instanceof ') + ']', 'instanceof !', '!instanceof ')}
    wrapAnchorWithSpan = true
    entryLevel = ${this.startingPoint ? 0 : 1}
    maximumLevels = 2

    attributes {
        class = Neos.Fusion:RawArray {
            namespace = 'nav-list'
            entryLevel = ${'-entry' + entryLevel}
            level = GesagtGetan.Basic:MenuLevel
        }
    }

    prepend = ''
    append = ''
    beforeItem = ''
    afterItem = ''

    site = ${site}

    normal.attributes.class = GesagtGetan.Basic:MenuElementClass
    active.attributes.class = GesagtGetan.Basic:MenuElementClass
    current.attributes.class = GesagtGetan.Basic:MenuElementClass

    link = GesagtGetan.Basic:MenuLink

    @process.shy = GesagtGetan.Basic:AlwaysReplaceWithShy
}